/*
   RadioHead attiny85 DHT22 Weather Station

   2021 Stefan Ostermann based on several source from the internetz.
   
   Sources:
   https://git.cryhost.de/crycode/attiny85-radiohead-dht22-weather-sensor/-/tree/master
*/


// pin with the LED connected
#define LED_PIN 4

// blink time for the LED
#define LED_TIME 200

// pin of the DHT22 sensor
#define DHT_PIN 1

// the own RadioHead address
#define RH_OWN_ADDR 0xca // 202

// the server RadioHead address
#define RH_SERVER_ADDR 0x01

// RadioHead bitrate in bit/s
#define RH_SPEED 2000

// pins for the radio hardware
#define RH_RX_PIN 5 // not used, set to a non-existent pin
#define RH_TX_PIN 3
#define RH_PTT_PIN 5 // not used, set to a non-existent pin

#include <Arduino.h>
#include <avr/sleep.h>
#include <avr/wdt.h>
#include <util/delay.h>

// for watchdog wakeup
// https://gist.github.com/dwhacks/8055287
#ifndef cbi
#define cbi(sfr, bit) (_SFR_BYTE(sfr) &= ~_BV(bit))
#endif
#ifndef sbi
#define sbi(sfr, bit) (_SFR_BYTE(sfr) |= _BV(bit))
#endif


// DHT22 lib
// not using the current adafruit dht library, because it eats too many memory
#include "dht22.h"
dht22 dht;

#define RH_BUF_LEN 5
uint8_t rh_buf[RH_BUF_LEN] = { 0x00, 0x00, 0x00, 0x00, 0x00 };

// reduce the RadioHead max message length to save memory
#define RH_ASK_MAX_MESSAGE_LEN RH_BUF_LEN

// RadioHead
#include <RH_ASK.h>

#define MSG_START 0x00
#define MSG_TEMP 0x01
#define MSG_HUMID 0x02
#define MSG_ERR 0xee


RH_ASK rh_driver(RH_SPEED, RH_RX_PIN, RH_TX_PIN, RH_PTT_PIN);

// watchdog flag
volatile boolean f_wdt = 1;

// temp / humid toggle
volatile boolean toggle = 0;


void gotoSleep(void);

void setup() {
  // setup the LED pin
  pinMode(LED_PIN, OUTPUT);

  // init the DHT22
  dht_init(&dht, DHT_PIN);


  uint8_t num_blink = 3;

  if (!rh_driver.init()) {
    num_blink = 5;
  }

  // blink 3 times
  for (uint8_t i = 0; i < num_blink; i++) {
    digitalWrite(LED_PIN, HIGH);
    _delay_ms(LED_TIME);
    digitalWrite(LED_PIN, LOW);
    _delay_ms(LED_TIME);
  }

  // send start message
  rh_buf[0] = MSG_START;
  rh_send(1);

  setup_watchdog(6); // approximately 4 seconds sleep

}

// main loop
void loop() {

  if (f_wdt) {
    f_wdt = 0;
    // turn on the LED
    digitalWrite(LED_PIN, HIGH);

    // temperature and humidity
    float t = 0;//float is 32bit = 1byte
    float h = 0;

    // read from the sensor and check if it was successfull
    if (dht_read_data(&dht, &t, &h) == 1) {
      // normal message

      if (toggle) {
        rh_buf[0] = MSG_TEMP;
        memcpy(&rh_buf[1], &t, 4);
      } else {
        rh_buf[0] = MSG_HUMID;
        memcpy(&rh_buf[1],&h,4);
      }
      toggle = !toggle;

      rh_send(RH_BUF_LEN);

    } else {
      // error message
      rh_buf[0] = MSG_ERR;
      rh_send(1);

    }

    // turn off the LED
    digitalWrite(LED_PIN, LOW);
    system_sleep();
    //_delay_ms(1000);
  }

}


// function to send RadioHead messages from the buffer
void rh_send(uint8_t len) {
  rh_driver.send((uint8_t *)rh_buf, len);
  rh_driver.waitPacketSent();
}



ISR(WDT_vect)
{
  f_wdt = 1; // set global flag
}

/* set system into the sleep state
   system wakes up when watchdog is timed out
*/
void system_sleep() {
  cbi(ADCSRA, ADEN);                   // switch Analog to Digitalconverter OFF

  set_sleep_mode(SLEEP_MODE_PWR_DOWN); // sleep mode is set here
  sleep_enable();

  sleep_mode();                        // System sleeps here

  sleep_disable();                     // System continues execution here when watchdog timed out
  sbi(ADCSRA, ADEN);                   // switch Analog to Digitalconverter ON
}

/* 0=16ms, 1=32ms,2=64ms,3=128ms,4=250ms,5=500ms
   6=1 sec,7=2 sec, 8=4 sec, 9= 8sec
*/
void setup_watchdog(int ii) {

  byte bb;
  int ww;
  if (ii > 9 ) ii = 9;
  bb = ii & 7;
  if (ii > 7) bb |= (1 << 5);
  bb |= (1 << WDCE);
  ww = bb;

  MCUSR &= ~(1 << WDRF);
  // start timed sequence
  WDTCR |= (1 << WDCE) | (1 << WDE);
  // set new watchdog timeout value
  WDTCR = bb;
  WDTCR |= _BV(WDIE);
}